home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / pc / LOGIC Apple II 5.25" Library - DOS Part 3 / DOS077A.dsk / PAYMENT SCHEDULE.bas < prev    next >
BASIC Source File  |  2012-02-16  |  4KB  |  91 lines
  1. 1  REM  THIS PROGRAM USES A PRINTER IN SLOT #1.  THERE IS PROVISION TO ENTER A HEADING FOR THE TABLES WHICH WILL BE PRINTED ON THE TABLE.
  2. 2  REM  IF YOUR PRINTER IS IN A DIFFERENT SLOT CHANGE SLOT # AT LINE 560.
  3. 3  REM  ALL INTEREST AMOUNTS MUST BE ENTERED AS DECIMALS THAT IS 10% IS ENTERED AS .10 AND 6% IS ENTERED AS .06.  INTEREST RATES ARE ANNUAL.
  4. 10  TEXT : HOME : VTAB 8
  5. 20  PRINT "PAYMENT PROGRAM"
  6. 30  PRINT "WRITTEN BY NELSON GOTHIE"
  7. 40  PRINT "MAY 1979"
  8. 50  FOR A = 1 TO 500
  9. 60  NEXT A
  10. 70  HOME : VTAB 8: PRINT "THIS PROGRAM WILL..."
  11. 75  CLEAR 
  12. 80  PRINT : PRINT "1. CALCULATE THE AMOUNT OF THE MONTHLY     PAYMENT": PRINT 
  13. 90  PRINT "2. PREPARE PRINCIPAL INTEREST TABLES": PRINT 
  14. 100  PRINT "3. CALCULATE THE NUMBER OF MONTHS TO       PAY OFF THE DEBT."
  15. 105  PRINT : PRINT "TO EXIT PROGRAM ENTER 4"
  16. 110  PRINT : PRINT "ENTER THE NUMBER OF THE PORTION DESIRED": INPUT B
  17. 120  IF B = 1 GOTO 200
  18. 130  IF B = 2 GOTO 400
  19. 140  IF B = 3 GOTO 600
  20. 145  IF B = 4 GOTO 1000
  21. 150  PRINT : INVERSE : PRINT "YOU MUST ENTER A NUMBER BETWEEN 1 AND 3": NORMAL : GOTO 80
  22. 200  HOME : VTAB 8: PRINT "CALCULATION OF MONTHLY PAYMENT"
  23. 210  PRINT : PRINT "ENTER THE ANNUAL INTEREST RATE": INPUT AIR
  24. 220  PRINT : PRINT "ENTER THE TOTAL AMOUNT TO BE FINANCED": INPUT TAF
  25. 230  PRINT : PRINT "ENTER THE NUMBER OF MONTHS OF THE LOAN": INPUT NM
  26. 240  REM  PAYMENT=PRINCIPAL TIMES INTEREST PER MONTH DIVIDED BY 1-(1+MONTHLY INT)RAISED TO THE -NM POWER
  27. 250 MI = AIR/12
  28. 260 C = (1 +MI) ^ -NM
  29. 270 PAY = TAF *(MI/(1 -C))
  30. 274 PAY =  INT(PAY *100 +.5)/ INT(100 +.5)
  31. 280  PRINT : PRINT "THE MONTHLY PAYMENT IS ...$";PAY
  32. 290  PRINT : PRINT "WOULD YOU LIKE A PRINCIPAL-INTERST      TABLE? Y/N": INPUT Q$
  33. 300  IF Q$ = "N"  THEN 70
  34. 305 MP = PAY
  35. 307 AF = TAF
  36. 310  IF Q$ = "Y"  THEN 452
  37. 400  HOME : VTAB 8
  38. 410  PRINT "THIS PORTION PREPARES PRINCIPAL AND INTEREST TABLES"
  39. 420  PRINT : PRINT "ENTER THE AMOUNT TO BE FINANCED": INPUT AF
  40. 430  PRINT : PRINT "ENTER THE ANNUAL INTEREST RATE EG .08": INPUT AIR
  41. 440  PRINT : PRINT "ENTER THE MONTHLY PAYMENT": INPUT MP
  42. 450  IF AF *(AIR/12) > = MP  THEN  GOTO 590
  43. 452  GOSUB 800
  44. 453  PRINT : PRINT "DO YOU WANT A PRINTED RECOED? Y/N": INPUT P$: IF P$ = "Y"  THEN  GOSUB 560
  45. 454  PRINT : PRINT "NO" SPC( 2)"INTEREST","PRINCIPAL" SPC( 7)"BALANCE"
  46. 455 N = 0
  47. 460 I = AF *(AIR/12)
  48. 470 P = MP -I
  49. 480 AF = AF -P
  50. 482 J =  INT((I *100) +.5)/100
  51. 484 R =  INT(AF *100)/100
  52. 485 N = N +1
  53. 486 Q =  INT(P *100)/100
  54. 490  PRINT N SPC( 3)J,Q,R
  55. 492  IF AF = 0  THEN  GOTO 545
  56. 495  IF AF *(AIR/12) +AF < = MP  THEN  GOTO 510
  57. 500  GOTO 460
  58. 510 I = AF *(AIR/12)
  59. 520 P = AF
  60. 530 AF = 0
  61. 540  GOTO 482
  62. 545  PRINT : PRINT "THE LAST PAYMENT IS.."J +Q
  63. 547  PR# 0
  64. 550  PRINT : PRINT "TO RETURN TO INDEX ENTER ANY LETTER": INPUT Q$: GOTO 70
  65. 560  PR# 1
  66. 565  PRINT "PRINCIPAL AND INTEREST TABLE"
  67. 567  PRINT : PRINT HEAD$
  68. 570  PRINT : PRINT "THIS TABLE REDUCES $"AF SPC( 1)"AT" SPC( 1)AIR *100;"% PER YEAR" SPC( 1)"PAYABLE AT $";MP SPC( 1)"PER MONTH."
  69. 575  RETURN 
  70. 590  PRINT : INVERSE : PRINT "THE MONTHLY PAYMENT WILL NOT REDUCE THE LOAN": NORMAL : GOTO 410
  71. 600  HOME : VTAB 8
  72. 610  PRINT "THIS SECTION CALCULATES THE NUMBER OF MONTHS REQUIRED TO PAY OFF A LOAN"
  73. 620  PRINT : PRINT "ENTER THE AMOUNT OF THE LOAN": INPUT AF
  74. 630  PRINT : PRINT "ENTER THE RATE OF INTEREST EG .08": INPUT AIR
  75. 640  PRINT : PRINT "ENTER THE DESIRED MONTHLY PAYMENT": INPUT MP
  76. 650  IF AF *(AIR/12) > = MP  THEN  PRINT "THE MONTHLY PAYMENT IS NOT LARGE ENOUGH TO REDUCE THE LOAN"
  77. 660  IF AF *(AIR/12) > = MP GOTO 610
  78. 670 K = MP/(MP -(AF *(AIR/12)))
  79. 680 C = 1 +(AIR/12)
  80. 690  FOR X =  INT(AF/MP) TO 1000
  81. 700 Y = C ^X
  82. 710  IF 1000 *Y > = 1000 *K GOTO 730
  83. 720  NEXT X
  84. 725  PRINT 
  85. 730  PRINT "THE LOAN WILL REDUCE IN "X" PAYMENTS"
  86. 740  PRINT : PRINT "WOULD YOU LIKE A PRINCIPAL-INTEREST     TABLE? Y/N": INPUT Q$
  87. 750  IF Q$ = "N"  THEN 70
  88. 760  IF Q$ = "Y"  THEN 452
  89. 800  PRINT : PRINT "IF YOU WISH A HEADIND FOR THIS SCHEDULE ENTER THE HEADING. IF NOT ENTER 'N'": INPUT HEAD$: IF HEAD$ = "N"  THEN HEAD$ = ""
  90. 810  RETURN 
  91. 1000  END